接着bat，两个文件

https://github.com/leejohannes/Scrcpy-Starto

文件在git上更新

还是Scrcpy启动器，把工具分开写入另外一个bat，增加根据ID连接，方便切换设备

第一个文件是Starto.bat

Scrcpy启动器

@echo off
title Scrcpy启动工具
cls
cd /d "%~dp0"
:start
echo.^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^
>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>
set c=<nul
adb devices -l
for /f %%i in (上次的IP) do set ip=%%i
echo.   回车 使用上次的IP：%ip%
echo.   1 连接ID
echo.   0 重启后/首次连接/打开工具
echo.   . 192.168.x.x
set /p ip=其他地址,请直接输入:
if "%ip%" equ "1" goto t
if "%ip%" equ "0" goto tool
if "%ip%" equ "." goto ip192
goto end
:t
set /p ip=输入transport_id:后的数字
for /f "delims=:" %%i in ('adb devices -l ^|find /i "transport_id:%ip%"') do set ip=%%i
goto end
:ip192
set /p ip=192.168.
set ip=192.168.%ip%
:end
echo. 输的入手机IP是%ip%，如果输入有误等待半分钟自动跳转
set b=0
for /f %%i in ('adb devices ^|find /i "%ip%"') do set b=1
if %b% equ 0 ( for /f %%i in ('adb connect %ip% ^|find /i "connected"') do ( goto success ))
if %b% equ 0 ( echo 输入的IP无法连接，请打开手机相关功能并确认IP
goto start)
:success
set /p c=连接成功，按回车打开图形界面，输入其他继续连接
echo. %ip%>上次的IP
if not "%c%" equ "" goto start
start /i scrcpy-noconsole.exe -s %ip% 1>nul 2>nul
exit
:tool
start /i tool.bat
goto start

简化，把工具放入另外一个bat文件

并且丰富工具内容，文件名tool.bat

@echo off
title adbtool
cd /d "%~dp0"
cls 
echo. 先用数据线连接手机打开usb调试模式
echo. adb shell setprop service.adb.tcp.port 5555
echo. 然后关闭再打开usb调试模式（此方法针对未root）
echo. root手机设置好props，在终端中输入
echo. su
echo. start adbd
echo.=============================================
echo. 回车打开cmd，可回到启动器
echo. 不需要输入adb，输入2再打开一个工具
echo. adb devices       可缩写成    de，device
echo. adb connect       可缩写成    co，con，conn
echo. adb kill-server   可缩写成    kill
echo. adb start-server  可缩写成    start
echo. adb disconnect    可缩写成    dis
:begin
set input=<nul
set /p input=%~dp0^adb^>
if "%input%"=="" goto cmd
if "%input%"=="2" ( start /i tool.bat 
goto begin )
if "%input%"=="kill" set input=kill-server
if "%input%"=="start" set input=start-server
for /f "tokens=1-2" %%a in ( "%input%" ) do (
if %%a==co set input=connect %%b 
if %%a==con set input=connect %%b 
if %%a==conn set input=connect %%b
if %%a==de set input=devices %%b
if %%a==device set input=devices %%b
if %%a==dis set input=disconnect %%b
) 
set input=adb %input%
echo 运行%input%，结果：
%input%
goto begin
:cmd
echo. 输入    tool回到工具
echo.   starto回到启动器
cmd /k